archetype (adl_version=1.4; uid=c4e66393-fa68-4976-b106-4c26f870e465)
	openEHR-EHR-OBSERVATION.glasgow_coma_scale_paediatric.v0

concept
	[at0000]	-- Paediatric Glasgow Coma Scale (pGCS)
language
	original_language = <[ISO_639-1::en]>
description
	original_author = <
		["name"] = <"Heather Leslie">
		["organisation"] = <"Atomica Informatics">
		["email"] = <"heather.leslie@atomicainformatics.com">
		["date"] = <"2007-03-13">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"To record clinical responses of the child or infant to defined stimuli as an objective assessment of the level of consciousness that is also appropriate for age and ability.">
			use = <"Use to record clinical responses of the child or infant to defined stimuli as an objective assessment of the level of consciousness that is also appropriate for age and ability. It is commonly used to establish a baseline conscious state and neurological function assessment and/or to detect patients who may require immediate medical intervention.

The Glasgow coma scale has three subscales E (eye), V (verbal) and M (motor). In clinical practice all three subscales are reported individually plus the 'Total score', if applicable.

A recorded response for each of E, V and M is mandatory. If a response cannot be tested, then the 'Not Applicable' null flavour should be recorded; do not use the 'None' ordinal value to record a missing component. Details about the reason for not being able to test a response can be recorded in the 'Confounding factors' data element.

The 'Total score' can be derived as the sum of the recorded eye, motor and verbal response scores. It is not appropriate to report a 'Total score' when one or more components are not testable because the score will be artificially low - in this situation record the EVM profile instead.

The three response values are considered separately as well as their sum. The 'EVM profile' can be derived as a concatenation of each of the recorded eye, motor and verbal response scores. For example, E3 V4 M2 represents the conscious state of a subject who opens eyes to speech, utters incomprehensible sounds and has an extensor response to stimulation.

The minimum possible 'Total score' value is 3 (equivalent to E1 V1 M1) and the maximum possible is 15 (equivalent to E4 V5 M6).

In practical use, Glasgow coma scale is recorded as one component of clinical monitoring, using sequential and repeated point-in-time measurements. Date and time should be recorded for each measurement, as well as any factors that may influence interpretation of changes. Changes in 'Total score' or any E, V or M values may have as much clinical significance as the value recorded initially.">
			keywords = <"response", "motor", "verbal", "eye", "stimulus", "glasgow", "coma", "scale", "neurological", "responsiveness", "EMV", "conscious", "GCS", "trauma", "central nervous system", "consciousness">
			misuse = <"Not to be used for assessing adults - use OBSERVATION.glasgow_coma_scale for this purpose.">
			copyright = <"© openEHR Foundation">
		>
	>
	lifecycle_state = <"in_development">
	other_contributors = <"Tomas Alme, DIPS, Norway", "Nadim Anani, Karolinska Institutet, Sweden", "Vebjoern Arntzen, Oslo university hospital, Norway", "Koray Atalag, University of Auckland, New Zealand", "Silje Ljosland Bakke, Bergen Hospital Trust, Norway", "Lars Bitsch-Larsen, Haukeland University hospital, Norway", "Martin Boeker, Medical Center - University of Freiburg, Germany", "Marja Buur, Medisch Centrum Alkmaar/ Code24, Netherlands", "Margaret Campbell, Queensland Health, Australia", "Rong Chen, Cambio Healthcare Systems, Sweden", "Stephen Chu, Queensland Health, Australia", "Tamsin Cockayne, Australia", "Marc Cotran, identity vision systems, Canada", "Angela de Zwart, Orion Health, New Zealand", "Einar Fosse, National Centre for Integrated Care and Telemedicine, Norway", "Sebastian Garde, Ocean Informatics, Germany", "Christian Ghan, The Chris O'Brien Lifehouse at RPA, Australia", "William Goossen, Results 4 Care, Netherlands", "Heather Grain, Llewelyn Grain Informatics, Australia", "Birger Haarbrandt, Hannover Medical School, Germany", "Sam Heard, Ocean Informatics, Australia", "Oliver Hosking, Remote Health NT, Australia", "Evelyn Hovenga, EJSH Consulting, Australia", "Eugene Igras, IRIS Systems, Inc., Canada", "Sundaresan Jagannathan, Scottish NHS, United Kingdom", "Konstantinos Kalliamvakos, Cambio Healthcare Systems, Sweden", "Lars Karlsen, DIPS ASA, Norway", "Shinji Kobayashi, Kyoto University, Japan", "Sergey Kovalenko, Chelyabinsk Regional Children Hospital, Russia", "Heather Leslie, Ocean Informatics, Australia (Editor)", "Hallvard Lærum, Oslo University Hospital, Norway", "Luis Marco Ruiz, Norwegian Center for Integrated Care and Telemedicine, Norway", "Ian McNicoll, freshEHR Clinical Informatics, United Kingdom (Editor)", "Jeroen Meintjens, Medisch Centrum Alkmaar, Netherlands", "Andrej Orel, Marand d.o.o., Slovenia", "Michael Reynolds, Great Lakes Pediatric Associates, PLLC, United States", "Hossein Riazi, Iran", "Arturo Romero, SESCAM, Spain", "Jussara Rotzsch, UNB, Brazil", "Anoop Shah, University College London, United Kingdom", "Tony Shannon, NHS, United Kingdom", "Gary Sinclair, NT DoH, Australia", "Tim Sturgill, United States", "Soon Ghee Yap, Singapore General Hospital, Singapore">
	other_details = <
		["licence"] = <"This work is licensed under the Creative Commons Attribution-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-sa/3.0/.">
		["custodian_organisation"] = <"openEHR Foundation">
		["references"] = <"Crippen DW. Head Trauma - Presentation: Medscape Reference: Drugs, Diseases & Procedures [Internet]. WebMD LLC: c1994-2013; [updated 2012 Jun 21; accessed 2015 Mar 05]. Available from: http://emedicine.medscape.com/article/433855-overview#a0112.

Glasgow Coma Scale, draft archetype, NEHTA Clinical Knowledge Manager [Internet]. Australia: National eHealth Transition Authority. Authored: 2007 Mar 13. Available at: http://dcm.nehta.org.au/ckm/#showArchetype_1013.1.1160 (no longer available).

Teasdale G. Glasgow Coma Scale: The Glasgow structured approach to Assessment of the Glasgow Coma Scale [Internet]. Sir Graham Teasdale; 2014 [accessed 2019 Oct 08]. Available from: http://www.glasgowcomascale.org/ and http://www.glasgowcomascale.org/downloads/GCS-Assessment-Aid.pdf.

Teasdale G, Jennett B. Assessment of coma and impaired consciousness. A practical scale. Lancet. 1974 Jul 13;2(7872):81-4. doi: 10.1016/s0140-6736(74)91639-0. PubMed PMID: 4136544.

Teasdale GM, Murray L. Revisiting the Glasgow Coma Scale and Coma Score. Intensive Care Med. 2000 Feb;26(2):153-4. doi: 10.1007/s001340050037. PubMed PMID: 10784300.

V3 DCModels R1 I1 2010 Sep - Glasgow Coma Scale v0.75 [Internet]. Health Level Seven International. Published Jan 2014 [accessed 2019 Oct 08]. Available at: https://github.com/DetailedClinicalModels/Detailed-Clinical-Models/blob/master/Glasgow%20Coma%20Scale%20(GCS)/org.hl7.GlasgowComaScale(15pointversion)English-v0.75.pdf.">
		["current_contact"] = <"Heather Leslie, Atomica Informatics, heather.leslie@atomicainformatics.com">
		["original_namespace"] = <"org.openehr">
		["original_publisher"] = <"openEHR Foundation">
		["custodian_namespace"] = <"org.openehr">
		["MD5-CAM-1.0.1"] = <"1E756A5BC4064903D1E2066C1FCBD663">
		["build_uid"] = <"5da99e4a-b0ec-4e87-b340-c83942fb65d2">
		["revision"] = <"0.0.1-alpha">
	>

definition
	OBSERVATION[at0000] matches {    -- Paediatric Glasgow Coma Scale (pGCS)
		data matches {
			HISTORY[at0001] matches {    -- Event Series
				events cardinality matches {1..*; unordered} matches {
					EVENT[at0002] occurrences matches {0..*} matches {    -- Any event
						data matches {
							ITEM_TREE[at0003] matches {    -- Tree
								items cardinality matches {3..*; unordered} matches {
									ELEMENT[at0009] matches {    -- Best eye response (E)
										value matches {
											1|[local::at0010],
											2|[local::at0011],
											3|[local::at0012],
											4|[local::at0013]
										}
										null_flavour matches {
											DV_CODED_TEXT matches {
												defining_code matches {
													[openehr::273]
												}
											}
										}
									}
									ELEMENT[at0007] matches {    -- Best verbal response (V)
										value matches {
											1|[local::at0014],
											2|[local::at0015],
											3|[local::at0016],
											4|[local::at0017],
											5|[local::at0018]
										}
										null_flavour matches {
											DV_CODED_TEXT matches {
												defining_code matches {
													[openehr::273]
												}
											}
										}
									}
									ELEMENT[at0008] matches {    -- Best motor response (M)
										value matches {
											1|[local::at0019],
											2|[local::at0020],
											3|[local::at0021],
											4|[local::at0022],
											5|[local::at0023],
											6|[local::at0024]
										}
										null_flavour matches {
											DV_CODED_TEXT matches {
												defining_code matches {
													[openehr::273]
												}
											}
										}
									}
									ELEMENT[at0026] occurrences matches {0..1} matches {    -- Total score
										value matches {
											DV_COUNT matches {
												magnitude matches {|3..15|}
											}
										}
									}
									ELEMENT[at0030] occurrences matches {0..1} matches {    -- EVM profile
										value matches {
											DV_TEXT matches {*}
										}
									}
									ELEMENT[at0037] occurrences matches {0..*} matches {    -- Comment
										value matches {
											DV_TEXT matches {*}
										}
									}
								}
							}
						}
						state matches {
							ITEM_TREE[at0040] matches {    -- Tree
								items cardinality matches {0..*; unordered} matches {
									ELEMENT[at0041] occurrences matches {0..*} matches {    -- Confounding factors
										value matches {
											DV_TEXT matches {*}
										}
									}
								}
							}
						}
					}
				}
			}
		}
		protocol matches {
			ITEM_TREE[at0038] matches {    -- Tree
				items cardinality matches {0..*; unordered} matches {
					allow_archetype CLUSTER[at0039] occurrences matches {0..*} matches {    -- Extension
						include
							archetype_id/value matches {/.*/}
					}
				}
			}
		}
	}


ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Paediatric Glasgow Coma Scale (pGCS)">
					description = <"Fifteen point scale used to assess impairment of consciousness in response to defined stimuli in a child or infant.">
					comment = <"More correctly known as the Modified Glasgow Coma Scale for Infants and Children">
				>
				["at0001"] = <
					text = <"Event Series">
					description = <"@ internal @">
				>
				["at0002"] = <
					text = <"Any event">
					description = <"Default, unspecified point in time or interval event which may be explicitly defined in a template or at run-time.">
				>
				["at0003"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0007"] = <
					text = <"Best verbal response (V)">
					description = <"Best verbal response to test stimulus.">
					comment = <"Most commonly, the score for verbal response will be selected from one of the ordinal values, however if a response cannot be tested, for example if the subject of care is intubated, then the \"Not Applicable\" null flavour should be recorded.">
				>
				["at0008"] = <
					text = <"Best motor response (M)">
					description = <"Best motor response to test stimulus.">
					comment = <"Most commonly, the score for motor response will be selected from one of the ordinal values, however if a response cannot be tested, for example if the subject of care cannot move their limbs due to injury or paralysis, then the \"Not Applicable\" null flavour should be recorded.">
				>
				["at0009"] = <
					text = <"Best eye response (E)">
					description = <"Best response of eyes to test stimulus.">
					comment = <"Most commonly, the score for eye response will be selected from one of the ordinal values, however if a response cannot be tested, for example if the subject of care cannot physically open their eyes due to other injuries, then the \"Not Applicable\" null flavour should be recorded.">
				>
				["at0010"] = <
					text = <"None">
					description = <"No response to any stimulus and no interfering factors. For example: eyes physically closed due to local swelling.">
				>
				["at0011"] = <
					text = <"To pain">
					description = <"Eyes opening in response to pain only.">
				>
				["at0012"] = <
					text = <"To sound">
					description = <"Eyes opening after verbal stimuli. Not to be confused with wakening of a sleeping person.">
				>
				["at0013"] = <
					text = <"Spontaneous">
					description = <"Eyes open before stimulus.">
				>
				["at0014"] = <
					text = <"None">
					description = <"No verbal response and no interfering factor. For example: intubation or profound deafness.">
				>
				["at0015"] = <
					text = <"Child: Sounds OR Infant: Moans in response to pain">
					description = <"Child makes incomprehensible words or non-specific sounds; Infant moans in response to pain.">
				>
				["at0016"] = <
					text = <"Child: Words OR Infant: Cries in response to pain">
					description = <"Child makes intelligible single words; Infant cries in response to pain.">
				>
				["at0017"] = <
					text = <"Child: Confused OR Infant: Irritable cries">
					description = <"Child is not orientated but communicates; Infant cries irritably.">
				>
				["at0018"] = <
					text = <"Child: Orientated OR Infant: Coos and babbles">
					description = <"Child oriented and appropriate; Infant coos or babbles as normal.">
				>
				["at0019"] = <
					text = <"None">
					description = <"No movement in arms/legs and no interfering factor. For example: paralysis.">
				>
				["at0020"] = <
					text = <"Abnormal extension">
					description = <"Decerebrate extension of arms and/or legs in response to stimuli. For example: extending arm at elbow.">
				>
				["at0021"] = <
					text = <"Abnormal flexion">
					description = <"Slow, decorticate flexion of arms and/or legs. For example: bends arm at elbow, but features predominantly abnormal.">
				>
				["at0022"] = <
					text = <"Normal flexion">
					description = <"Withdraws in response to pain. For example: flexion of wrist when supra-orbital pressure applied; pulls part of body away when nailbed pinched.">
				>
				["at0023"] = <
					text = <"Localising">
					description = <"Withdraws to touch. For example: brings hand above the clavicle when supra-orbital pressure is applied.">
				>
				["at0024"] = <
					text = <"Child: obeys commands OR Infant: Moves spontaneously and purposefully">
					description = <"Child follows verbal request for movement; Infant moves as expected.">
				>
				["at0026"] = <
					text = <"Total score">
					description = <"The sum of the ordinal scores recorded for each of the three component responses.">
					comment = <"The Total Score may be derived as the sum of the three response data elements and, if so, should be validated by the clinical information system against the individual scores entered by the clinician to ensure there is no conflict or inconsistency. Do not report a total score when one or more components are not testable because the score will be artificially low - in this situation record the EVM profile.">
				>
				["at0030"] = <
					text = <"EVM profile">
					description = <"Alternative assessment to 'Total Score' where the Eye Verbal Motor profile is expressed as three discrete components.">
					comment = <"The EMV Score may be automatically derived as a concatenation of the three response data elements and, if so, should be validated by the clinical information system against the individual scores entered by the clinician to ensure there is no conflict or inconsistency. The 'Not applicable' null flavour value should be recorded as 'NT', for 'not tested' as per http://www.glasgowcomascale.org/.">
				>
				["at0037"] = <
					text = <"Comment">
					description = <"Additional narrative about the measurement of the scale not captured in other fields.">
					comment = <"Record the reasons for inability to test in the 'Confounding factors' data element.">
				>
				["at0038"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0039"] = <
					text = <"Extension">
					description = <"Additional information required to capture local content or to align with other reference models/formalisms.">
					comment = <"For example: local information requirements or additional metadata to align with FHIR or CIMI equivalents.">
				>
				["at0040"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0041"] = <
					text = <"Confounding factors">
					description = <"Narrative record of factors that may have contributed to the GCS scores.">
					comment = <"For example: deafness; aphasia; language issues; use of sedatives; hypothermia; or paralysis, severe facial/eye swelling or tracheal intubation as reasons for inability to record any one of the ordinal E, V or M assessments.">
				>
			>
		>
	>