archetype (adl_version=1.4; uid=b188108d-128e-4221-9cc8-1b459d31690b)
	openEHR-EHR-OBSERVATION.affected_body_surface_area-burn.v0
specialise
	openEHR-EHR-OBSERVATION.affected_body_surface_area.v0

concept
	[at0000.1]	-- Burn-affected body surface area
language
	original_language = <[ISO_639-1::en]>
description
	original_author = <
		["name"] = <"Heather Leslie">
		["organisation"] = <"Atomica Informatics">
		["email"] = <"heather.leslie@atomicainformatics.com">
		["date"] = <"2020-10-06">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"To record details about the estimated proportion of body surface area affected by a burn injury.">
			use = <"Use to record details about the estimated proportion of body surface area affected by a burn injury, including the total body surface area affected, the body surface area affected per body site and the body surface area affected per severity.

This archetype has been designed as a component of a templated full burn assessment which may comprise a range of ENTRY archetypes and nested CLUSTERs, describing the history, physical examination findings, and other measurements.">
			keywords = <"TBSA", "BSA", "burn", "surface", "area", "burns", "assessment", "Lund-Browder", "skin", "rule", "nines", "palmar", "method", "TBSA%">
			misuse = <"Not to be used to record the measured or calculated body surface area of an individual - use the OBSERVATION.body_surface_area for this purpose.

Not to be used to record the estimated proportion of body surface area affected by other conditions of the skin - use the parent archetype OBSERVATION.affected_body_surface_area for this purpose.">
			copyright = <"© openEHR Foundation">
		>
	>
	lifecycle_state = <"in_development">
	other_contributors = <"Silje Ljosland Bakke, Helse Vest IKT AS, Norway (openEHR Editor)", "Heather Leslie, Atomica Informatics, Australia (openEHR Editor)", "Åsa Skagerhult, Region Östergötland, Sweden (openEHR Editor)", "Erik Sundvall, Region Östergötland + Linköping University, Sweden (openEHR Editor)">
	other_details = <
		["licence"] = <"This work is licensed under the Creative Commons Attribution-ShareAlike 4.0 International License. To view a copy of this license, visit http://creativecommons.org/licenses/by-sa/4.0/.">
		["custodian_organisation"] = <"openEHR Foundation">
		["references"] = <"Burn Management Guidelines [Internet]. Melbourne: Alfred Health. Paediatric Burn Assessment Ruler; 2007 [updated 2012 May 08; cited 2021 07 16]; Available from: https://www.vicburns.org.au/wp-content/uploads/2016/06/poster4-paediatric-burns-assessment-ruler.pdf.

Hettiaratchy S, Papini R. Initial management of a major burn: II--assessment and resuscitation. BMJ. 2004 Jul 10;329(7457):101-3. doi: 10.1136/bmj.329.7457.101. PMID: 15242917; PMCID: PMC449823. Available from https://www.ncbi.nlm.nih.gov/pmc/articles/PMC449823/.

Radiation Emergency Medical Management [Internet]. U.S. Department of Health & Human Services. Burn triage and treatment of thermal injuries in a radiation emergency; [updated 2021 May 14; cited 2021 Jul 16]. Available from: https://www.remm.nlm.gov/burns.htm.

Rhodes J, Clay C, Phillips M. The surface area of the hand and the palm for estimating percentage of total body surface area: results of a meta-analysis. Br J Dermatol. 2013 Jul;169(1):76-84. doi: 10.1111/bjd.12290. PMID: 23448271.

Scarisbrick JJ, Morris S. How big is your hand and should you use it to score skin in cutaneous T-cell lymphoma? Br J Dermatol. 2013 Aug;169(2):260-5. doi: 10.1111/bjd.12403. PMID: 23621659.

The Royal Children's Hospital Melbourne [Internet]. Melbourne: The Royal Children's Hospital. Burns unit: Clinical information; [cited 2021 07 16]. Available from: 
https://www.rch.org.au/burns/clinical_information/#Lund_and_Browder_chart

Wikipedia [Internet]. Wikimedia Foundation, Inc. Lund and Browder chart; [updated 2021 Mar 23; cited 2021 Jul 16]; Available from: https://en.wikipedia.org/wiki/Lund_and_Browder_chart.

Wikipedia [Internet]. Wikimedia Foundation, Inc. Total body surface area; [updated 2018 Jul 06; cited 2021 Jul 16]; Available from: https://en.wikipedia.org/wiki/Total_body_surface_area.">
		["original_namespace"] = <"org.openehr">
		["original_publisher"] = <"openEHR Foundation">
		["custodian_namespace"] = <"org.openehr">
		["MD5-CAM-1.0.1"] = <"8F4DBE7C7F8924D18DC5EC1629F0FB68">
		["build_uid"] = <"25bb1107-42ed-48f8-aaa2-37f79d99df85">
		["revision"] = <"0.0.1-alpha">
	>

definition
	OBSERVATION[at0000.1] matches {    -- Burn-affected body surface area
		data matches {
			HISTORY[at0001] matches {    -- History
				events cardinality matches {0..*; unordered} matches {
					EVENT[at0002] occurrences matches {0..*} matches {    -- Any event
						data matches {
							ITEM_TREE[at0003] matches {    -- Tree
								items cardinality matches {0..*; unordered} matches {
									ELEMENT[at0004.1] occurrences matches {0..1} matches {    -- Condition name
										value matches {
											DV_CODED_TEXT matches {
												defining_code matches {
													[local::at0.1]    -- Burn
												}
											}
										}
									}
									ELEMENT[at0005] occurrences matches {0..1} matches {    -- Description
										value matches {
											DV_TEXT matches {*}
										}
									}
									ELEMENT[at0014] occurrences matches {0..1} matches {    -- Total body surface area (TBSA) affected
										value matches {
											DV_PROPORTION matches {
												numerator matches {|0.0..100.0|}
												type matches {2}
											}
										}
									}
									CLUSTER[at0006] occurrences matches {0..*} matches {    -- Per body site
										items cardinality matches {1..*; unordered} matches {
											ELEMENT[at0007] matches {    -- Body site name
												value matches {
													DV_TEXT matches {*}
												}
											}
											ELEMENT[at0008] occurrences matches {0..1} matches {    -- Site surface area
												value matches {
													DV_PROPORTION matches {
														numerator matches {|0.0..100.0|}
														type matches {2}
													}
												}
											}
											ELEMENT[at0010] occurrences matches {0..1} matches {    -- Affected site surface area
												value matches {
													DV_PROPORTION matches {
														numerator matches {|0.0..100.0|}
														type matches {2}
													}
												}
											}
											CLUSTER[at0011] occurrences matches {0..1} matches {    -- Per severity
												items cardinality matches {1..*; unordered} matches {
													ELEMENT[at0012] matches {    -- Severity
														value matches {
															DV_TEXT matches {*}
														}
													}
													ELEMENT[at0013] matches {    -- Affected site surface area
														value matches {
															DV_PROPORTION matches {
																numerator matches {|0.0..100.0|}
																type matches {2}
															}
														}
													}
												}
											}
										}
									}
									CLUSTER[at0015] occurrences matches {0..1} matches {    -- Total body surface area per severity
										items cardinality matches {1..*; unordered} matches {
											ELEMENT[at0016] matches {    -- Severity
												value matches {
													DV_TEXT matches {*}
												}
											}
											ELEMENT[at0017] matches {    -- Total body surface area affected
												value matches {
													DV_PROPORTION matches {
														numerator matches {|0.0..100.0|}
														type matches {2}
													}
												}
											}
										}
									}
									allow_archetype CLUSTER[at0018] occurrences matches {0..*} matches {    -- Additional detail
										include
											archetype_id/value matches {/.*/}
									}
									allow_archetype CLUSTER[at0019] occurrences matches {0..*} matches {    -- Image representation
										include
											archetype_id/value matches {/openEHR-EHR-CLUSTER\.media_file(-[a-zA-Z0-9_]+)*\.v1/}
									}
									ELEMENT[at0020] occurrences matches {0..1} matches {    -- Comment
										value matches {
											DV_TEXT matches {*}
										}
									}
									ELEMENT[at0.2] occurrences matches {0..1} matches {    -- Cause of burn
										value matches {
											DV_TEXT matches {*}
										}
									}
								}
							}
						}
					}
				}
			}
		}
		protocol matches {
			ITEM_TREE[at0009] matches {    -- Item tree
				items cardinality matches {0..*; unordered} matches {
					allow_archetype CLUSTER[at0021] occurrences matches {0..*} matches {    -- Extension
						include
							archetype_id/value matches {/.*/}
					}
				}
			}
		}
	}


ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000.1"] = <
					text = <"Burn-affected body surface area">
					description = <"Estimation of the proportion of body surface area affected by a burn.">
				>
				["at0004.1"] = <
					text = <"Condition name">
					description = <"The name of the injury or disease affected the skin.">
					comment = <"For example: burn; or psoriasis. Coding of the condition name with an external terminology is preferred, where possible. ">
				>
				["at0.1"] = <
					text = <"Burn">
					description = <"The condition is a burn.">
				>
				["at0.2"] = <
					text = <"Cause of burn">
					description = <"The aetiology of the burn.">
					comment = <"For example: thermal; cold; radiation; chemical; or electrical.">
				>
				["at0000"] = <
					text = <"Affected body surface area">
					description = <"Estimation of the proportion of body surface area affected by a skin injury or disease.">
				>
				["at0001"] = <
					text = <"History">
					description = <"@ internal @">
				>
				["at0002"] = <
					text = <"Any event">
					description = <"Default, unspecified point in time or interval event which may be explicitly defined in a template or at run-time.">
				>
				["at0003"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0004"] = <
					text = <"Condition name">
					description = <"The name of the injury or disease affected the skin.">
					comment = <"For example: burn; or psoriasis. Coding of the condition name with an external terminology is preferred, where possible. ">
				>
				["at0005"] = <
					text = <"Description">
					description = <"Narrative description about the affected body surface area assessment.">
				>
				["at0006"] = <
					text = <"Per body site">
					description = <"Details about body surface area affected at each body site.">
				>
				["at0007"] = <
					text = <"Body site name">
					description = <"The name of the body site assessed.">
					comment = <"Coding of the body site name with an external terminology is preferred, where possible. ">
				>
				["at0008"] = <
					text = <"Site surface area">
					description = <"The estimated percentage of total body surface area apportioned for the entire identified body site.">
					comment = <"For example: when using the 'Rule of nines' method of estimation, 9% is apportioned for each arm, 18% for the back of the torso, and 1% for the genitalia.">
				>
				["at0009"] = <
					text = <"Item tree">
					description = <"@ internal @">
				>
				["at0010"] = <
					text = <"Affected site surface area">
					description = <"The estimated extent of total body surface area affected at the identified body site.">
					comment = <"For example: when using the 'Rule of nines' method, if half of an arm is affected, the affected site surface area value is 4.5%; or if a third of the back is affected, the value is 6%.">
				>
				["at0011"] = <
					text = <"Per severity">
					description = <"Details about each severity of findings at the identified body site.">
				>
				["at0012"] = <
					text = <"Severity">
					description = <"The degree of severity of the condition at the identified site.">
					comment = <"For example: mild, moderate or severe for a rash; or first degree, second degree or third degree for a burn. Coding of the severity with an external terminology is preferred, where possible. It is expected that the severity values will be identical as the values used in the 'Affected body surface area per severity' cluster.">
				>
				["at0013"] = <
					text = <"Affected site surface area">
					description = <"The estimated extent of total body surface area affected by the degree of identified severity, at the identified body site.">
					comment = <"For example: when using the 'Rule of nines' method, if half of an arm is affected, the affected site surface area value is 4.5%; or if a third of the back is affected, the value is 6%.">
				>
				["at0014"] = <
					text = <"Total body surface area (TBSA) affected">
					description = <"The total sum of affected surface area across all body sites.">
					comment = <"For example: if 4.5% of an arm and 6% of the back is affected, then the TBSA is 10%.">
				>
				["at0015"] = <
					text = <"Total body surface area per severity">
					description = <"Details about the total sum of surface area affected per severity, across all body sites.">
				>
				["at0016"] = <
					text = <"Severity">
					description = <"The degree of severity of the condition.">
					comment = <"For example: mild, moderate or severe for a rash; or first degree, second degree or third degree for a burn. Coding of the severity with an external terminology is preferred, where possible. It is expected that the severity values will be identical as the values used in the 'Per severity' cluster.">
				>
				["at0017"] = <
					text = <"Total body surface area affected">
					description = <"The total sum of body surface area affected by the degree of the identified severity, across all body sites.">
					comment = <"For example: when using the 'Rule of nines' method, if half of an arm is affected, the affected site surface area value is 4.5 %; or if a third of the back is affected, the value is 6 %.">
				>
				["at0018"] = <
					text = <"Additional detail">
					description = <"Additional details about the estimation of affected body surface area.">
				>
				["at0019"] = <
					text = <"Image representation">
					description = <"Digital image, video or diagram representing the affected body surface area findings.">
				>
				["at0020"] = <
					text = <"Comment">
					description = <"Additional narrative about the estimation of affected body surface area, not captured in other fields.">
				>
				["at0021"] = <
					text = <"Extension">
					description = <"Additional information required to extend the model with local content or to align with other reference models or formalisms.">
					comment = <"For example: local information requirements; or additional metadata to align with FHIR.">
				>
			>
		>
	>