archetype (adl_version=1.4; uid=f368bd7f-2204-4356-b7df-5b4aea9e330a)
	openEHR-EHR-INSTRUCTION.health_education_request.v0

concept
	[at0000]	-- Health education request
language
	original_language = <[ISO_639-1::en]>
	translations = <
		["sv"] = <
			language = <[ISO_639-1::sv]>
			author = <
				["name"] = <"Annika Terner">
				["organisation"] = <"B3 Healthcare Consulting AB">
				["email"] = <"annika.terner@b3.se">
			>
			accreditation = <".">
		>
	>
description
	original_author = <
		["name"] = <"Heather Leslie">
		["organisation"] = <"Atomica Informatics">
		["email"] = <"heather.leslie@atomicainformatics.com">
		["date"] = <"2013-02-25">
	>
	details = <
		["sv"] = <
			language = <[ISO_639-1::sv]>
			purpose = <"Att registrera en begäran om rådgivning/undervisning/kommunikation avsedd att öka hälsokunskap och praktiska färdigheter.">
			use = <"Används för att registrera en begäran om rådgivning/undervisning/kommunikation avsedd att öka hälsokunskap och praktiska färdigheter (ofta relaterade till hälsotillstånd).">
			keywords = <"utbildning", "information">
			misuse = <"">
		>
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"To record an order for communication to improve health literacy and life skills.">
			use = <"Use to record an order for communication to improve health literacy and life skills.">
			keywords = <"education", "information">
			misuse = <"">
			copyright = <"© openEHR Foundation">
		>
	>
	lifecycle_state = <"in_development">
	other_contributors = <>
	other_details = <
		["licence"] = <"This work is licensed under the Creative Commons Attribution-ShareAlike 4.0 International License. To view a copy of this license, visit http://creativecommons.org/licenses/by-sa/4.0/.">
		["custodian_organisation"] = <"openEHR Foundation">
		["current_contact"] = <"Heather Leslie, Atomica Informatics<heather.leslie@atomicainformatics.com>">
		["original_namespace"] = <"org.openehr">
		["original_publisher"] = <"openEHR Foundation">
		["custodian_namespace"] = <"org.openehr">
		["MD5-CAM-1.0.1"] = <"374BCE34BED925AA798BEEB8A3528701">
		["build_uid"] = <"4e248125-01ec-4027-8578-c54cd1700015">
		["revision"] = <"0.0.1-alpha">
	>

definition
	INSTRUCTION[at0000] matches {	-- Health education request
		activities cardinality matches {0..*; unordered} matches {
			ACTIVITY[at0001] occurrences matches {0..1} matches {	-- Current Activity
				description matches {
					ITEM_TREE[at0002] matches {	-- Tree
						items cardinality matches {1..*; unordered} matches {
							ELEMENT[at0003] matches {	-- Topic
								value matches {
									DV_TEXT matches {*}
								}
							}
							ELEMENT[at0004] occurrences matches {0..*} matches {	-- Details
								value matches {
									DV_TEXT matches {*}
								}
							}
							ELEMENT[at0005] occurrences matches {0..1} matches {	-- Number of sessions
								value matches {
									DV_COUNT matches {
										magnitude matches {|>=1|}
									}
								}
							}
							ELEMENT[at0006] occurrences matches {0..1} matches {	-- Reason
								value matches {
									DV_TEXT matches {*}
								}
							}
							ELEMENT[at0007] occurrences matches {0..1} matches {	-- Proposed outcome
								value matches {
									DV_TEXT matches {*}
								}
							}
						}
					}
				}
			}
		}
		protocol matches {
			ITEM_TREE[at0008] matches {	-- Tree
				items cardinality matches {0..*; unordered} matches {
					allow_archetype CLUSTER[at0009] occurrences matches {0..*} matches {	-- Extension
						include
							archetype_id/value matches {/.*/}
					}
				}
			}
		}
	}


ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Health education request">
					description = <"Communication to improve health literacy and life skills.">
				>
				["at0001"] = <
					text = <"Current Activity">
					description = <"Current Activity.">
				>
				["at0002"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0003"] = <
					text = <"Topic">
					description = <"The headline topic of the education.">
				>
				["at0004"] = <
					text = <"Details">
					description = <"Narrative description about the proposed education.">
				>
				["at0005"] = <
					text = <"Number of sessions">
					description = <"The number of educational sessions to be undertaken.">
				>
				["at0006"] = <
					text = <"Reason">
					description = <"The reason for undertaking this education process.">
				>
				["at0007"] = <
					text = <"Proposed outcome">
					description = <"Narrative description about the goals or proposed outcome of the education.">
				>
				["at0008"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0009"] = <
					text = <"Extension">
					description = <"Additional information required to capture local content or to align with other reference models/formalisms.">
					comment = <"For example: local information requirements or additional metadata to align with FHIR or CIMI equivalents.">
				>
			>
		>
		["sv"] = <
			items = <
				["at0000"] = <
					text = <"Begäran om hälsorådgivning/information/undervisning">
					description = <"Kommunikation avsedd att öka hälsokunskap och praktiska färdigheter (ofta relaterade till hälsotillstånd).">
				>
				["at0001"] = <
					text = <"Aktuell aktivitet">
					description = <"Aktuell aktivitet.">
				>
				["at0002"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0003"] = <
					text = <"Ämne">
					description = <"Ämnesrubrik för hälsorådgivningen/informationen/undervisningen.">
				>
				["at0004"] = <
					text = <"Detaljer">
					description = <"Berättande beskrivning av den föreslagna utbildningen.">
				>
				["at0005"] = <
					text = <"Antal tillfällen">
					description = <"Antalet undervisningstillfällen som ska genomföras.">
				>
				["at0006"] = <
					text = <"Orsak">
					description = <"Anledningen till att utföra denna utbildningsomgång.">
				>
				["at0007"] = <
					text = <"Förslag på resultat">
					description = <"Berättande beskrivning av målen eller det föreslagna resultatet av utbildningen.">
				>
				["at0008"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0009"] = <
					text = <"Utökning">
					description = <"Plats för att infoga ytterligare information som krävs för att fånga upp lokalt innehåll eller för att anpassa sig till andra referensmodeller/format.">
					comment = <"Till exempel: Lokala informationskrav eller ytterligare metadata för att anpassa sig till FHIR- eller CIMI-motsvarigheter.">
				>
			>
		>
	>